[PServer-Funktion]Einlogg-Bonus

[Syntaxfehler]

Huhu,
ich habe mal eine Einlogg-Bonus-Funktion geschrieben.
Sie vergibt jeden Tag Cash und ein Item oder auch mehrere Items...
Einfach in der TGLOBAL_GSP eine neue Funktion erstellen und dies hier einsetzen.

 TGiveLoginBonus

/*
	[Code from: Syntaxfehler]
*/

CREATE PROCEDURE [dbo].[TGiveLoginBonus]
	@dwUserID INT
AS
BEGIN
	-- Variables
	DECLARE @dwCash INT = 0
	DECLARE @dLastGiven DATE = null
	DECLARE @bGive INT = 1
	-- Variables (you can change)
	DECLARE @dwAddCash INT = 1
	DECLARE @wItemID INT = 7602
	DECLARE @wItemCount INT = 5

	-- Bonus already given?
	SELECT @dLastGiven = dLastGiven, @bGive = dwGetBonus FROM TCOMEBACKTABLE WHERE dwUserID = @dwUserID
	IF(@@rowcount = 0)
		SET @bGive = 2
	IF(@bGive != 0)
	BEGIN
		IF(@dLastGiven = CONVERT(date, GetDate()))
			SET @bGive = 0
	END

	-- Give bonus
	IF(@bGive = 1 OR @bGive = 2)
	BEGIN
		-- Give cash
		SELECT @dwCash = dwCash FROM TCASHTESTTABLE WHERE dwUserID = @dwUserID
		UPDATE TCASHTESTTABLE SET dwCash = @dwCash + @dwAddCash WHERE dwUserID = @dwUserID
		IF(@@rowcount = 0)
			INSERT INTO TCASHTESTTABLE(dwUserID, dwCash, dwBonus)VALUES(@dwUserID, @dwAddCash, 0)
		-- Give item
		INSERT INTO TCASHITEMCABINETTABLE(
		dwUserID, wItemID, bLevel, bCount, bGLevel,
		dwDuraMax, dwDuraCur, bRefineCur, dEndTime, bGradeEffect,
		bMagic1, bMagic2, bMagic3, bMagic4, bMagic5, bMagic6,
		wValue1, wValue2, wValue3, wValue4, wValue5, wValue6,
		dwTime1, dwTime2, dwTime3, dwTime4, dwTime5, dwTime6)VALUES(
		@dwUserID, @wItemID, 0, @wItemCount, 0,
		0, 0, 0, '1900-01-01 00:00:00', 0,
		0, 0, 0, 0, 0, 0,
		0, 0, 0, 0, 0, 0,
		0, 0, 0, 0, 0, 0)
	END
	IF(@bGive = 1)
	BEGIN
		UPDATE TCOMEBACKTABLE SET dLastGiven = CONVERT(date, GetDate()) WHERE dwUserID = @dwUserID
	END
	IF(@bGive = 2)
	BEGIN
		INSERT INTO TGLOBAL_GSP.dbo.TCOMEBACKTABLE(
		dwUserID, dwGetBonus, dLastGiven, dwLastSilver, dLastGivenSilver)VALUES(
		@dwUserID, 1, CONVERT(date, GetDate()), 0, '1900-01-01')
	END
END

@dwAddCash = Wieviel MS man bekommt
@wItemID = Welches Item man bekommt
@wItemCount = Wieviel von diesem Item

#UPDATE: Silber-Bonus!

 TGiveSilverBonus

/*
	[Code from: Syntaxfehler]
*/

CREATE PROCEDURE [dbo].[TGiveSilverBonus]
	@dwUserID INT,
	@dwCharID INT
AS
BEGIN
	-- Variables
	DECLARE @dLastGivenSilver DATE = null
	DECLARE @dwLastSilver INT = 0
	DECLARE @bGive INT = 1
	DECLARE @szRecvName VARCHAR(50)
	DECLARE	@bLenTitle BINARY(4)
	DECLARE	@bLenMessage BINARY(4)
	DECLARE @szT VARCHAR(8)
	DECLARE @szM VARCHAR(8)
	-- Variables (you can change)
	DECLARE @dwAddSilver INT = 10
	DECLARE @dwMaxSilver INT = 40
	DECLARE @szSender VARCHAR(50) = 'Administrator'
	DECLARE @szTitle VARCHAR(256) = 'Willkommen zurück!'
	DECLARE @szMessage VARCHAR(2048) = '(DEIN TEXT)'

	-- Do not change (taken from TEventItemGive)!
	SET @bLenTitle = DATALENGTH(@szTitle)
	SET @bLenMessage = DATALENGTH(@szMessage)
	SET @szT = RIGHT(master.dbo.fn_sqlvarbasetostr(@bLenTitle), 8)
	SET @szTitle  = @szT + @szTitle
	SET @szM = RIGHT(master.dbo.fn_sqlvarbasetostr(@bLenMessage), 8)
	SET @szMessage = @szM + @szMessage

	-- Silver already given?
	SELECT @dLastGivenSilver = dLastGivenSilver, @bGive = dwGetBonus
	FROM TCOMEBACKTABLE WHERE dwUserID = @dwUserID
	IF(@@rowcount = 0) -- then there is something wrong!
		SET @bGive = 2
	IF(@bGive != 0)
	BEGIN
		IF(@dLastGivenSilver = CONVERT(date, GetDate()))
			SET @bGive = 0
		IF(@dLastGivenSilver = '1900-01-01')
		BEGIN
			SET @bGive = 0
			UPDATE TCOMEBACKTABLE SET dLastGivenSilver = CONVERT(date, GetDate())
			WHERE dwUserID = @dwUserID
		END
	END

	-- Give silver
	IF(@bGive = 1 OR @bGive = 2)
	BEGIN
		-- Get information from TCOMEBACKTABLE
		SELECT @dwLastSilver = dwLastSilver FROM TCOMEBACKTABLE WHERE dwUserID = @dwUserID
		-- Get name of character
		SELECT @szRecvName = szName FROM TGAME_GSP.dbo.TCHARTABLE WHERE dwCharID = @dwCharID
		
		-- Check date
		IF(DATEDIFF(day, @dLastGivenSilver, CONVERT(date, GetDate())) > 1)
			SET @dwLastSilver = 0
		-- Check maximum
		IF(@dwMaxSilver = @dwLastSilver OR @dwMaxSilver < @dwLastSilver)
			SET @dwLastSilver = @dwMaxSilver - @dwAddSilver

		-- Send silver
		INSERT INTO TGAME_GSP.dbo.TPOSTTABLE(dwCharID, szSender, dwSendID, szRecvName, szTitle,
		szMessage, bType, bRead, dwGold, dwSilver, dwCooper, timeRecv)VALUES(
		@dwCharID, @szSender, 0, @szRecvName, @szTitle, @szMessage, 0, 0, 0,
		@dwLastSilver + @dwAddSilver, 0, GetDate())
	END
	IF(@bGive = 1)
	BEGIN
		UPDATE TCOMEBACKTABLE
		SET dLastGivenSilver = CONVERT(date, GetDate()), dwLastSilver = @dwLastSilver + @dwAddSilver
		WHERE dwUserID = @dwUserID
	END
	IF(@bGive = 2) -- then there is something wrong!
	BEGIN
		INSERT INTO TCOMEBACKTABLE(
		dwUserID, dwGetBonus, dLastGiven, dwLastSilver, dLastGivenSilver)VALUES(
		@dwUserID, 1, CONVERT(date, GetDate()), @dwAddSilver, CONVERT(date, GetDate()))
	END
END

@dwAddSilver = Wieviel Silber es pro Tag gibt
@dwMaxSilver = Maximal erreichbare Silber-Anzahl
@szSender = Der Absender vom Brief
@szTitle = Der Brief-Titel
@szMessage = Der Text im Brief

In die TEnterServer-Funktion (auch TGLOBAL_GSP) müssen jetzt noch folgende
Zeilen eingefügt werden:

 Code für TEnterServer

EXEC TGiveLoginBonus @dwUserID
EXEC TGiveSilverBonus @dwUserID, @dwCharID

Damit diese Funktionen funktionieren wird eine extra Tabelle benötigt.
Folgende Datei kann per "Dump SQL File" in der TGLOBAL_GSP ausgeführt werden und fügt die entsprechende Tabelle hinzu.



In der TCOMEBACKTABLE ist auch dwGetBonus zu finden, dadurch kann man Accounts vom Einlogg-Bonus ausschließen.

Hoffe ihr könnt mit der Funktion was anfangen.

[joniator12]

gut. dann brauch ich den leuten kein cash mehr händisch eintragen thx man!!
Skillartz bitte eintragen^^
Thx

[Syntaxfehler]

Was genau funktioniert denn nicht?
Ich habe im Moment nicht die Möglichkeit ein Video-Tutorial zu machen.

Hast du alles richtig gemacht?

Also, du erstellst eine neue Funktion, fügst den Code aus dem ersten
Spoiler ein und speicherst sie.
Dann öffnest du die Funktion TEnterServer und fügst ein oder zwei Zeilen (da ist ja immer Abstand zwischen)
noch vor COMMIT TRAN TENTERSERVER die Zeile aus dem zweiten Spoiler ein!

Falls es immernoch nicht klappt, muss ich gucken, ob ich das mit dem Video-TuT vielleicht
doch mal zum Funktionieren kriege.

[Syntaxfehler]

Ganz oben in Zeile 1-3 muss Folgendes stehen:

 Spoiler

ALTER PROCEDURE [dbo].[TGiveLoginBonus]
	@dwUserID INT
AS

Da wird nämlich @dwUserID deklariert.

Ich gehe davon aus, dass du nur den Teil darunter kopiert hattest.

[Syntaxfehler]

#UPDATE: Silber-Bonus! (in Beitrag #1 zu finden)

Vergibt jeden Tag die angegebene Menge an Silber!

[Bukkit123]

hättest du Lust ein Video Tut zu machen ?

Sonst sehr gut danke ^^

[Syntaxfehler]

Originally Posted by Bukkit123

hättest du Lust ein Video Tut zu machen ?

Momentan eher nicht, sorry. :/

Originally Posted by Bukkit123

Sonst sehr gut danke ^^

Schön, wenn es gefällt ^^

[Bukkit123]

Wann genau tritt der bonus ein?

[Shyras]

Originally Posted by Bukkit123

Wann genau tritt der bonus ein?

Alle 24 Stunden Beim Einloggen.
Okay nich 24 Stunden aber an bekommts erst am Nächsten Tag

[JustKill95]

wie erstellt man eine neue function pls melden

[TheKiingZ]

Geh in Navicat, such deine SQL-Verbindung, klick auf TGLOBAL_GSP, dann dbo und dann oben auf Function. Dann mach einfach rechts klick und drück auf New Function.
Mfg TheKiingZ

[Arise4Story]

Danke funktioniert <3